Создание классической змейки gms2 и стиль программирования - Создание игр - Статьи по созданию игр

Код

/// @description scr_snCreateFood(null)
/// @function scr_snCreateFood
/// @param null

var posX = irandom_range(0, room_width-global.TILE_WIDTH);
var posY = irandom_range(0, room_height-global.TILE_HEIGHT);

//данный цикл проверяет чтобы в ячейке куда ставится еда, не было узлов, вы можете догадаться тут не проверяется o_head, т.е. еда вполне может появиться в голове
//это легко исправить, оставлю это задачу вам (подсказка можно создать еще один parent, либо решить задачу с использованием p_node и для o_head)
while(collision_rectangle(posX+1, posY+1, posX+global.TILE_WIDTH, posY+global.TILE_HEIGHT, p_node,
false, false)){
  posX = irandom_range(0, room_width-global.TILE_WIDTH);
  posY = irandom_range(0, room_HEIGHT-global.TILE_HEIGHT);
}

//оператор div это аналог floor(posX / global.TILE_WIDTH) не правда ли хорошо, когда есть такой оператор на уровне языка
posX = posX div global.TILE_WIDTH * global.TILE_WIDTH;
posY = posY div global.TILE_HEIGHT * global.TILE_HEIGHT;

var obj = instance_create_layer(posX, posY, "Main", o_food);

Код

/// @description move=true
_prevX = x;
_prevY = y;

_move = true;

alarm[0] = _alarm0;

Код

/// @description f_snChangeDirection(int_direction)
/// @function f_snChangeDirection
/// @param int_direction

var input_direction = argument0;

if(this.direction == input_direction) return input_direction;
switch(input_direction){

  case dir_down:
  if(this.direction == dir_up) return this.direction;
  break;

  case dir_up:
  if(this.direction == dir_down) return this.direction;
  break;

  case dir_left:
  if(this.direction == dir_right) return this.direction;
  break;

  case dir_right:
  if(this.direction == dir_left) return this.direction;
  break;

}
return input_direction;

Код

/// @description scr_pos_to_dir(speed, direction)
/// @function scr_pos_to_dir
/// @param speed
/// @param direction

var spd = argument0;
var dir = argument1;

var len, hspd, vspd;
len = (spd);
hspd = lengthdir_x(len, dir);
vspd = lengthdir_y(len, dir);
x += hspd;
y += vspd;

Код

/// @description scr_snHeadKill(null)
/// @function scr_snHeadKill
/// @param null

alarm[0] = -1;
_move = false;
sprite_index = spr_red_dead;

Код

/// @description scr_snMove(null)
/// @function scr_snMove
/// @param null

//тот самый момент когда мы проверяем направление непосредственно перед движением
direction = f_snChangeDirection(_newDirection);

//меняем позицию в зависимости от направления
scr_pos_to_dir(_speed, direction);

//перебираем все узлы и меняем им позицию отсюда сразу после того как передвинулась наша голова
//по сути сегменты змейки, просто меняют свое положение на предыдущее положение их _owner
var obj = null;

for(var i = 0; i<instance_number(o_node); i++){
  obj = instance_find(o_node, i);

  obj._prevX = obj.x;
  obj._prevY = obj.y;
  obj.x = obj._owner._prevX;
  obj.y = obj._owner._prevY;
}

Код

/// @description

//ввод user'a
if(keyboard_check(ord("W"))){
  _newDirection = f_snChangeDirection(dir_up);
}
else
if(keyboard_check(ord("S"))){
  _newDirection = f_snChangeDirection(dir_down);
}
else
if(keyboard_check(ord("A"))){
  _newDirection = f_snChangeDirection(dir_left);
}
else
if(keyboard_check(ord("D"))){
  _newDirection = f_snChangeDirection(dir_right);
}

//_вспоминаем alarm[0] именно там мы и меняем _move на true
if(_move){

  _move = false;
  scr_snMove();

}
//origin left_top
//проверяем все что может убить нашу змейку
//знаете почему именно x+1? мне пришлось так сделать чтобы узлы не сталкивались с границами змейки при движении например вверх или вниз
//дело в frame системе движка, но не критично, я просто по сути обрезал прямоугольник на 1 пиксель программно, можно также например вручную поменять маску спрайтов
//что было бы даже логичнее, но мне было важно это указать в коде, чтобы он мне сказал "эй парень, тут ты когда-то сказал обрезать, помни об этом"
//дело каждого, делайте как вам удобнее
if(collision_rectangle(x+1, y+1, x + _width-1, y + _height-1, p_node, false, true)){
  scr_snHeadKill();
}
//ну и понятно проверяем выход за границы игрового экрана
if(x<0){
  x = 0;
  scr_snHeadKill();
}
if(x>room_width){
  x = room_width-_width;
  scr_snHeadKill();
}
if(y<0){
  y = 0;
  scr_snHeadKill();
}
if(y>room_height){
  y = room_height-_height;
  scr_snHeadKill();
}

Код

/// @description scr_snAddNode(null)
/// @function scr_snAddNode
/// @param null

var obj = null;
var newObj = null;
for(var i = 0; i<instance_number(o_node); i++){
obj = instance_find(o_node, i);
}
//перебираем все узлы, obj и будет нашим последним узлом, за которым мы и добавим наш следующий

var posX = 0;
var posY = 0;

var dX = lengthdir_x(global.TILE_WIDTH, -direction);
var dY = lengthdir_y(global.TILE_HEIGHT, -direction);
posX = obj.x+dX;
posY = obj.y+dY;

//вспомните скрипт scr_pos_to_dir, фактически это копипаст от туда, только с заменой на -direction, мне нужно было сделать именно так, т.е. таким образом
//в независимости от направления он поместит следующих узел за последним

var newObj = instance_create_layer(posX, posY, "Main", o_node);
newObj._owner = obj.id; //и назначит хозяином, последний узел из перебора

Код

scr_snAddNode();

instance_destroy(other.id);

scr_snCreateFood();

Исходник вы можете скачать здесь.

Очень надеюсь урок был кому-то понятен. Это мой первый опыт написания подобного. Понятно, что в данном уроке требуется определенный, но небольшой уровень понимания кода. Однако, если вы будете даже просто перепечатывать, у вас получится это понять чисто по наитию.

Могу ошибаться, но согласно правилам я вроде бы нечего не нарушил. Данный материал полностью уникален. Т.е. если я и буду писать данную статью в будущем где-то еще, я напишу ее заново и по другому. Также я не воспользовался правом залить файлы на гугл-диск. Чтобы не нагружать лишний раз сервер сайта лишними файлами.
Картинку из гугл диска материал воспринимать отказался, пришлось загрузить сюда.