//Константы
fric = 0.4;             //коэффициент трения скольжения
g = 9.8                 //ускорение свободного падения

d = 0.8;                //диаметр эквивалентного круга

if(!phy_sleeping)   //Только если не спит!
{
     //Сила трения скольжения
     Ff = fric * phy_mass * g;
     direction = point_direction(phy_position_x, phy_position_y, phy_position_xprevious, phy_position_yprevious);
     xFf = lengthdir_x(Ff, direction);
     yFf = lengthdir_y(Ff, direction);
      
     if (phy_speed_ms(phy_speed) > (Ff / phy_mass) / 60)
     {
         physics_apply_force(x, y, xFf, yFf);
     }
     else
     {
         phy_speed_x = 0;
         phy_speed_y = 0;
     }
      
     //Момент трения вращения
     s = (pi * power(d, 2))/4;               //площадь эквивалентного круга
     q = (phy_mass * g) / s;                 //давление на опору(для круга)
     Mf = (pi/12) * q * fric * power(d, 3);
      
     if (abs(phy_angular_velocity) > radtodeg((Mf / phy_inertia) / 60))
     {
         physics_apply_torque(sign(phy_angular_velocity) * -Mf);
     }
     else
     {
         phy_angular_velocity = 0;
     }
}

phy_bullet = true;      //Режим физической пули
P = 50;                 //Сила взрыва
Imin = 0.5              //Минимальный импульс ударной волны, до которого считать          

//Параметры траектории
direction = point_direction(xstart, ystart, mouse_x, mouse_y);
phy_rotation = -1*direction;
physics_apply_local_impulse(0, 0, 10, 0);

distmax = P / Imin;        //Максимальный радиус расчета взрыва

//Перебираем объекты
with (dynamic_obj)
{    
     //Проверяем на попадние в зону взрыва
     if rectangle_in_circle(bbox_left, bbox_top, bbox_right, bbox_bottom, other.x, other.y, other.distmax) > 0
     {
         //Перебираем линии
         ang0 = point_direction(other.x, other.y, x, y);  //устанавливаем угол на объект
         ang = ang0;
         cw_flag = false;
         acw_flag = false;
          
         while (!cw_flag || !acw_flag)
         {
             collision = false;
              
             //Определяем точку попадания
             for(dist = 1; dist <= other.distmax; dist += 2)
             {
                 xcol = other.x + lengthdir_x(dist, ang);
                 ycol = other.y + lengthdir_y(dist, ang);
                      
                 if collision_point(xcol, ycol, id, true, false)
                 {
                     I = other.P / dist;
                     xI = lengthdir_x(I, ang);
                     yI = lengthdir_y(I, ang);
                     collision = true;
                      
                     physics_apply_impulse(xcol, ycol, xI, yI);
                     //effect_create_above(ef_spark, xcol, ycol, 0, c_yellow); //светим попадание
                     break;
                 }
             }
             if(collision)
             {
                 if(!cw_flag) {ang -= 1;}
                 else {ang += 1;}
             }
             else
             {
                 if(!cw_flag)
                 {
                     cw_flag = true;
                     ang = ang0 + 1;
                 }
                 else {acw_flag = true;}
             }     
         }
     }
}

effect_create_above(ef_explosion, x, y, 0, c_white);
audio_play_sound(snd_boom1, 1, 0);
instance_destroy();