Прицел снайперки для UDK - Движки для разработки игр и сложные системы разработки - Unreal Engine

Прицел снайперки для UDK

Дата: Четверг, 03 Марта 2011, 19:06 | Сообщение # 1

Игродел - одиночка

Сейчас нет на сайте

Люди помогите.Я создаю снайперку,но никак не пойму как создать для нее снайперский прицел.Как это делают в играх,можете просветить?И еще какой параметр в скрипте отвечает за точность(пользуюсь скриптом Пруфа из Unreal-level.ru)?

Vortex

Дата: Понедельник, 14 Марта 2011, 07:43 | Сообщение # 2

частый гость

Сообщений: 41

Сейчас нет на сайте

Quote (bs1)

PPeople help. I'm creating a sniper, but can not understand how to create her sniper scope. How to do it in games, you can enlighten? And what parameter in the script is responsible for the accuracy (I use a script Proof of Unreal-level.ru)?

See the UTWeap_SniperRiffle script from UT3

simulated function DrawZoomedOverlay( HUD H )
{
local float ScaleX, ScaleY, StartX;
local float OldOrgX, OldOrgY, OldClipX, OldClipY;

// the sniper overlay is a special case that we want to ignore the safe region
OldOrgX = H.Canvas.OrgX;
OldOrgY = H.Canvas.OrgY;
OldClipX = H.Canvas.ClipX;
OldClipY = H.Canvas.ClipY;
H.Canvas.OrgX = 0.0;
H.Canvas.OrgY = 0.0;
H.Canvas.ClipX = H.Canvas.SizeX;
H.Canvas.ClipY = H.Canvas.SizeY;

bDisplayCrosshair = false;

ScaleY = H.Canvas.ClipY/768.0;
ScaleX = ScaleY;
StartX = 0.5*H.Canvas.ClipX - 512.0*ScaleX;

if ( (Instigator == None) || (Instigator.PlayerReplicationInfo == None)
|| (Instigator.PlayerReplicationInfo.Team == None) || (Instigator.PlayerReplicationInfo.Team.TeamIndex == 0) )
{
H.Canvas.SetDrawColor(255,48,0);
}
else
{
H.Canvas.SetDrawColor(64,64,255);
}

// Draw the crosshair
// Draw the 4 corners
H.Canvas.SetPos(StartX, 0.0);
H.Canvas.DrawTile(HudMaterial, 512.0 * ScaleX, 384.0 * ScaleY, 2, 0, 510, 383);

H.Canvas.SetPos(H.Canvas.ClipX*0.5, 0.0);
H.Canvas.DrawTile(HudMaterial, 512.0 * ScaleX, 384.0 * ScaleY, 510, 0, -510, 383);

H.Canvas.SetPos(StartX, H.Canvas.ClipY*0.5);
H.Canvas.DrawTile(HudMaterial, 512.0 * ScaleX, 384.0 * ScaleY, 2, 383, 510, -383);

H.Canvas.SetPos(H.Canvas.ClipX*0.5, H.Canvas.ClipY*0.5);
H.Canvas.DrawTile(HudMaterial, 512.0 * ScaleX, 384.0 * ScaleY, 510, 383, -510, -383);

if ( StartX > 0 )
{
// Draw the Horizontal Borders
H.Canvas.SetPos(0.0, 0.0);
H.Canvas.DrawTile(HudMaterial, StartX, 384.0 * ScaleY, 1, 0, 3, 383);

H.Canvas.SetPos(H.Canvas.ClipX - StartX, 0.0);
H.Canvas.DrawTile(HudMaterial, StartX, 384.0 * ScaleY, 4, 0, -3, 383);

H.Canvas.SetPos(0.0, H.Canvas.ClipY*0.5);
H.Canvas.DrawTile(HudMaterial, StartX, 384.0 * ScaleY, 1, 383, 3, -383);

H.Canvas.SetPos(H.Canvas.ClipX - StartX, H.Canvas.ClipY*0.5);
H.Canvas.DrawTile(HudMaterial, StartX, 384.0 * ScaleY, 4, 383, -3, -383);
}

// restore the canvas parameters
H.Canvas.OrgX = OldOrgX;
H.Canvas.OrgY = OldOrgY;
H.Canvas.ClipX = OldClipX;
H.Canvas.ClipY = OldClipY;
}

Сообщение отредактировал Vortex - Понедельник, 14 Марта 2011, 07:54

Bs1

Дата: Понедельник, 14 Марта 2011, 08:29 | Сообщение # 3

Игродел - одиночка

Сообщений: 1801

Сейчас нет на сайте

Thanks,Vortex,but I don't have UT3 installed yet...

Vortex

Дата: Понедельник, 14 Марта 2011, 08:35 | Сообщение # 4

частый гость

Сообщений: 41

Сейчас нет на сайте

/**
* Copyright 1998-2007 Epic Games, Inc. All Rights Reserved.
*/
class UTWeap_SniperRifle extends UTWeapon;

var class<UTDamageType> HeadShotDamageType;
var float HeadShotDamageMult;

var Texture2D HudMaterial;

var array<MaterialInterface> TeamSkins;

/** headshot scale factor when moving slowly or stopped */
var float SlowHeadshotScale;

/** headshot scale factor when running or falling */
var float RunningHeadshotScale;

/** Zoom minimum time*/
var bool bAbortZoom;

/** sound while the zoom is in progress */
var audiocomponent ZoomLoop;
var soundcue ZoomLoopCue;

/** Whether the standard crosshair should be displayed */
var bool bDisplayCrosshair;

/** tracks number of zoom started calls before zoom is ended */
var int ZoomCount;

var float FadeTime;

//-----------------------------------------------------------------
// AI Interface

function float SuggestAttackStyle()
{
return -0.4;
}

function float SuggestDefenseStyle()
{
return 0.2;
}

function float GetAIRating()
{
local UTBot B;
local float ZDiff, dist, Result;

B = UTBot(Instigator.Controller);
if ( B == None )
return AIRating;
if ( B.IsShootingObjective() )
return AIRating - 0.15;
if ( B.Enemy == None )
return AIRating;

if ( B.Stopped() )
result = AIRating + 0.1;
else
result = AIRating - 0.1;
if ( Vehicle(B.Enemy) != None )
result -= 0.2;
ZDiff = Instigator.Location.Z - B.Enemy.Location.Z;
if ( ZDiff < -200 )
result += 0.1;
dist = VSize(B.Enemy.Location - Instigator.Location);
if ( dist > 2000 )
{
if ( !B.LineOfSightTo(B.Enemy) )
result = result - 0.15;
return ( FMin(2.0,result + (dist - 2000) * 0.0002) );
}
if ( !B.LineOfSightTo(B.Enemy) )
return AIRating - 0.1;

return result;
}

function bool RecommendRangedAttack()
{
local UTBot B;

B = UTBot(Instigator.Controller);
if ( (B == None) || (B.Enemy == None) )
return true;

return ( VSize(B.Enemy.Location - Instigator.Location) > 2000 * (1 + FRand()) );
}

simulated function ProcessInstantHit( byte FiringMode, ImpactInfo Impact )
{
local float Scaling;
local int HeadDamage;

if( (Role == Role_Authority) && !bUsingAimingHelp )
{
if (Instigator == None || VSize(Instigator.Velocity) < Instigator.GroundSpeed * Instigator.CrouchedPct)
{
Scaling = SlowHeadshotScale;
}
else
{
Scaling = RunningHeadshotScale;
}

HeadDamage = InstantHitDamage[FiringMode]* HeadShotDamageMult;
if ( (UTPawn(Impact.HitActor) != None && UTPawn(Impact.HitActor).TakeHeadShot(Impact, HeadShotDamageType, HeadDamage, Scaling, Instigator.Controller)) ||
(UTVehicleBase(Impact.HitActor) != None && UTVehicleBase(Impact.HitActor).TakeHeadShot(Impact, HeadShotDamageType, HeadDamage, Scaling, Instigator.Controller)) )
{
SetFlashLocation(Impact.HitLocation);
return;
}
}

super.ProcessInstantHit( FiringMode, Impact );
}