; монстр в лабиринте
; УТОЧНЕНИЕ: n монстров в лабиринте 100х100(?) клеточек
:генератор
invkill
perkill
maxxr = 8 ; кол-во комнат по горизонтали
maxyr = 8 ; кол-во комнат по вертикали
maxx = maxxr*2+1 ; кол-во ячеек(комнаты+стены/проходы) по горизонтали
maxy = maxyr*2+1 ; кол-во ячеек по горизонтали
crx=0 ; переменные- счётчики
:цикл1_x
crx=crx+1
cry=0
:цикл1_y
cry=cry+1
world_#crx$_#cry$ = 1 ; заполняем мир
if cry<maxy then goto цикл1_y
if crx<maxx then goto цикл1_x
maxap=1 ; кол-во активных точек
x1=2*rnd#maxxr$ ; координаты первой активной точки
y1=2*rnd#maxyr$ ; точки всегда указывают на комнаты
world_#x1$_#y1$=2 ; создаём первую пустую комнату
:генератор_выбор_точки
t=rnd#maxap$ ; выбираем текущую активную точку
crn=0 ; счётчик направлений пробива
dir1=0 & dir2=0 & dir3=0 & dir4=0
if world_#x#t$ $_#y#t$ -2$= 1 then crn=crn+1 & dir1=1; пробив возможен: север
if world_#x#t$ -2$_#y#t$ $= 1 then crn=crn+1 & dir2=1; запад
if world_#x#t$ $_#y#t$ +2$= 1 then crn=crn+1 & dir3=1; юг
if world_#x#t$ +2$_#y#t$ $= 1 then crn=crn+1 & dir4=1; восток
if crn>0 then dir=rnd#crn$ & goto пробиватор
if crn=0 then x#t$= x#maxap$ & y#t$= y#maxap$ & maxap=maxap-1 ; гасим точку
if maxap>0 then goto генератор_выбор_точки
if maxap=0 then goto начало
end
:пробиватор
ndir=0
if dir1=1 then ndir=ndir+1
if dir=ndir then goto пробив1
if dir2=1 then ndir=ndir+1
if dir=ndir then goto пробив2
if dir3=1 then ndir=ndir+1
if dir=ndir then goto пробив3
if dir4=1 then ndir=ndir+1
if dir=ndir then goto пробив4
end
:пробив1
world_#x#t$ $_#y#t$ -1$=2 & world_#x#t$ $_#y#t$ -2$=2 ; пробиваем проход и делаем комнату
maxap=maxap+1 ; добавляем новую активную точку
x#maxap$=x#t$ ; указывающую на эту комнату
y#maxap$=y#t$-2
goto генератор_выбор_точки
end
:пробив2
world_#x#t$ -1$_#y#t$ $=2 & world_#x#t$ -2$_#y#t$ $=2
maxap=maxap+1 ; добавляем новую активную точку
x#maxap$=x#t$-2 ; указывающую на эту комнату
y#maxap$=y#t$
goto генератор_выбор_точки
end
:пробив3
world_#x#t$ $_#y#t$ +1$=2 & world_#x#t$ $_#y#t$ +2$=2
maxap=maxap+1 ; добавляем новую активную точку
x#maxap$=x#t$ ; указывающую на эту комнату
y#maxap$=y#t$+2
goto генератор_выбор_точки
end
:пробив4
world_#x#t$ +1$_#y#t$ $=2 & world_#x#t$ +2$_#y#t$ $=2 ; пробиваем проход и делаем комнату
maxap=maxap+1 ; добавляем новую активную точку
x#maxap$=x#t$+2 ; указывающую на эту комнату
y#maxap$=y#t$
goto генератор_выбор_точки
end
:начало
ggrx= 2 & ggry= 7 & instr ggface= север
ggx=ggrx*2 & ggy=ggry*2
instr letters= a b c d e f g h
tokens letters
instr w1= стена
instr w2= выход
instr ситуац= /в тупике/на прямом пути/на повороте/на развилке/на перекрёстке/
:начало_метка_1
pln
pln я- монстр. стою в комнате #%token#ggrx$$#9-ggry$, мордой на #%ggface$.
pln на севере- #%w#world_#ggx$_#ggy-1$$$, на западе- #%w#world_#ggx-1$_#ggy$$$, на юге- #%w#world_#ggx$_#ggy+1$$$, на востоке- #%w#world_#ggx+1$_#ggy$$$.
crn=0
dir1=0 & dir2=0 & dir3=0 & dir4=0
if world_#ggx$_#ggy-1$= 2 then crn=crn+1 & dir1=1; выход: север
if world_#ggx-1$_#ggy$= 2 then crn=crn+1 & dir2=1; выход: запад
if world_#ggx$_#ggy+1$= 2 then crn=crn+1 & dir3=1; выход: юг
if world_#ggx+1$_#ggy$= 2 then crn=crn+1 & dir4=1; выход: восток
if crn=1 then ситуац = "в тупике" & goto м_назад ; идём в единств возм сторону
; на момент начала игры монстр может оказаться в тупике лицом в любую сторону
if (crn=2)and(dir1=dir3) then ситуац = "на прямом пути" & goto м_дальше ; идём куда угодно, Только НЕ назад
; монстр теоретически может оказаться на прямом пути лицом к стене на момент начала игры
if (crn=2)and(dir1<>dir3) then ситуац = "на повороте" & goto м_дальше ; идём куда угодно, Только НЕ назад
if crn=3 then ситуац = "на развилке" & goto м_дальше ; идём куда угодно, Только НЕ назад
if crn=4 then ситуац = "на перекрёстке" & goto м_дальше ; идём куда угодно, Только НЕ назад
: начало_метка_2
pln так что я нахожусь #%ситуац$, и пойду теперь на #%ggface$
; перемещаем монстра:
if ggface="север" then ggry=ggry-1 & ggy=ggy-2
if ggface="запад" then ggrx=ggrx-1 & ggx=ggx-2
if ggface="юг" then ggry=ggry+1 & ggy=ggy+2
if ggface="восток" then ggrx=ggrx+1 & ggx=ggx+2
btn начало_метка_1, press ENTER
end
:м_назад
if dir1=1 then ggface="север"
if dir2=1 then ggface="запад"
if dir3=1 then ggface="юг"
if dir4=1 then ggface="восток"
goto начало_метка_2
end
:м_дальше
crn=crn-1 ; отбрасываем одно направление (назад)
dir = rnd#crn$
if ((dir<=1)and(not(ggface="юг" )))and(dir1=1) then ggface="север" & goto начало_метка_2
if ((dir<=2)and(not(ggface="восток")))and(dir2=1) then ggface="запад" & goto начало_метка_2
if ((dir<=3)and(not(ggface="север" )))and(dir3=1) then ggface="юг" & goto начало_метка_2
if ((dir<=4)and(not(ggface="запад" )))and(dir4=1) then ggface="восток" & goto начало_метка_2
end