//xx,yy точка в которую надо двигаться танку.
//tdir, dir - Направление корпуса и пушки.
//setangle - Код плавного поворота(DreamRunner'a вроде)

if hp<1
{
    instance_destroy();
    exit;
}

if distance_to_point(xx,yy)>2
{
    if path_index=-1 or (xx!=path_get_point_x(path_index, path_get_number(path_index)-1) and yy!=path_get_point_y(path_index, path_get_number(path_index)-1))
    {
        var path=path_add();
        if !mp_grid_path(obj_server.cells,path,x,y,xx,yy,true) {xx=x;yy=y;path_end();exit;}
        path_start(path,1,0,true)
    }
    if direction!=dir
    {
        dir=set_angle(dir,direction,2)
        path_speed=0
    }
    else
    {
        path_speed=1
    }
}
else
{
    path_end();
}

if target=-1
{
    if tdir!=dir {tdir=set_angle(tdir,dir,4)};
    var dist=120;
    with obj_teamp
    {
        if !collision_line(x,y,other.x,other.y,obj_wall,0,1)
        {
            if color!=other.color and object_index!=obj_bull
            {
                if distance_to_object(other)<dist
                {
                    other.target=id
                    dist=distance_to_object(other)
                }
            }
        }
    }
    if target!=-1 {alarm[10]=2}
}
else
{
    if !instance_exists(target) or collision_line(x,y,target.x,target.y,obj_wall,0,1) {alarm[10]=2;target=-1;exit;}
    if tdir!=point_direction(x,y,target.x,target.y) {tdir=set_angle(tdir,point_direction(x,y,target.x,target.y),4)}    
    if alarm[0]=-1
    {
        if abs(tdir-point_direction(x,y,target.x,target.y))<3
        {
            with instance_create(x,y,obj_bull)
            {
                direction=other.tdir
                speed=4
                color=other.color
                team=other.team
                dmg=irandom_range(10,20)
                stype=2
            }
            alarm[0]=40
        }
    }
}